Microsoft Office Excel
uređuje Dragan Grbić

Kreiranje liste formula

Nivo:
NIVO 3 - Prilozi na ovom nivou su namenjeni naprednim korisnicima, onima koji se već dobro snalaze u programima i onima koji već imaju iskustva u naprednim tehnikama. Ovom nivou pripadaju preporuke i trikovi koje bi trebalo da savlada svako ko teži dugotrajnom i efikasnom radu u Office programima.

Tu i tamo, zatrebaće vam da odjednom pregledate sve formule na radnom listu u Excelu. Za to postoji nekoliko načina, u zavisnosti od toga kakav pregled želite i koliko vremena za pripremu imate. Predlažemo da angažujete VBA...

Mnogi korisnici koji formiraju složenije strukture u Excelu kad-tad otkriju mogućnost direktog prikaza sadržaja formula direktno u ćelijama umesto rezultata, kako bi se mogao napraviti brzi pregled. Ako nikad niste probali, probajte sad: otvorite dijalog Tools/Options, pa na listu View uključite opciju Formulas. Međutim, Excel ne obezbeđuje nikakav automatski formirani pregled formula koji bi mogao poslužiti kao specifikacija ili tehnički opis rešenja na radnom listu.

Izvesnu kompenzaciju može da predstavlja pomoćno okno Watch Window, koje postoji tek počev od Excela 2002. Ovakav pregled ćete formirati nad odabranom ćelijom kada u kontekstnom meniju (desni klik miša) odaberete komandu Add Watch; tada ćete pored oznake imena radne sveske, radnog lista i adrese ćelije videti i vrednost i formulu. Međutim, mana ovog principa je u tome što morate ići od jedne do druge ćelije i definisati pregled. No, dobro - VBA može biti na usluzi. Ako definišete sledeći makro, sve formule na radnom listu će se njegovim pozivom odjednom prebaciti u okno Watch Window:

Sub OknoPregleda()

Dim Formule As Range, Celija As Range

' opseg ćelija sa formulama
'
On Error Resume Next
Set Formule = Range("A1").SpecialCells(xlFormulas, 23)

' prekid ako nema formula
'
If Formule Is Nothing Then
  MsgBox "Nas ovom listu nema formula!"
  Exit Sub
End If

' prebacivanje u Watch Window
'
For Each Celija In Formule
  Application.Watches.Add Celija
Next Celija

Application.ScreenUpdating = False

End Sub

Ovo radi posao na licu mesta, ali ovaj sadržaj je prikladan samo za pregled. Možda bi bilo prikladnije da napravite specifikaciju formula na novom radnom listu. Sa takvim sadržajem posle možete da uradite šta god želite: da ga odštampate, kopirate, odvojeno pregledate, itd. Taj posao će za vas izvesti sledeći makro.

Sub ListajFormule()

Dim Formule As Range, Celija As Range
Dim StranaPregleda As Worksheet
Dim Red As Integer

' opseg ćelija sa formulama
'
On Error Resume Next
Set Formule = Range("A1").SpecialCells(xlFormulas, 23)

' prekid ako nema formula
'
If Formule Is Nothing Then
  MsgBox "Nas ovom listu nema formula!"
  Exit Sub
End If

' Novi radni list za pregled
'
Application.ScreenUpdating = False
Set StranaPregleda = ActiveWorkbook.Worksheets.Add
StranaPregleda.Name = "Formule na listu " & _
   Formule.Parent.Name

' Formira se tabela pregleda
'
With StranaPregleda
  Range("A1") = "Adresa"
  Range("B1") = "Formula"
  Range("C1") = "Vrednost"
  Range("A1:C1").Font.Bold = True
End With

' Procesiranje formula
'
Red = 2
For Each Celija In Formule
  With StranaPregleda
    Cells(Red, 1) = Celija.Address(RowAbsolute:=False, _
        ColumnAbsolute:=False)
    Cells(Red, 2) = "-> " & Celija.Formula
    Cells(Red, 3) = Celija.Value
    Red = Red + 1
  End With
Next Celija

' Podešavanje širine kolona pregleda
'
StranaPregleda.Columns("A:C").AutoFit

Application.ScreenUpdating = False

End Sub