Microsoft Office Excel
uređuje Dragan Grbić

Automatske procedure pri otvaranju i zatvaranju

Nivo:
NIVO 3 - Prilozi na ovom nivou su namenjeni naprednim korisnicima, onima koji se već dobro snalaze u programima i onima koji već imaju iskustva u naprednim tehnikama. Ovom nivou pripadaju preporuke i trikovi koje bi trebalo da savlada svako ko teži dugotrajnom i efikasnom radu u Office programima.

Veoma je lako obezbediti posebne uslove rada Excela, uz pomoć rezervisanih makroa Auto_Open i Auto_Close.

Automatske procedure u Excelu 5/95

Koje operacije možete poželeti da izvršite prilikom ulaska u program? Nije teško aranžirati otvaranje nekog dokumenta - to se radi direktno, duplim klikom na ikonu datoteke. Recimo, možda biste hteli radnu površinu potpuno rasterećenu od svih elemenata, poput opcije Full Screen. Ako izaberete View/Full Screen, nestaju samo naslovna linija programa i toolbar, a ostaju mnogi drugi elementi. Radnu površinu možete osloboditi upravo kroz Auto_Open. Možda za neku posebnu primenu želite da podesite rad štampača drugačije nego što je to uobičajeno. Čak, možete napraviti sasvim posebno definisan meni. Ulaskom u dokument možete automatski resetovati sadržaj nekog obrasca. Na tom mestu može da stoji makro koji smo vam dali u prošlom pasusu... Prepustite mašti na volju i usput zadovoljite potrebe u radu. Prilažemo sasvim jednostavne procedure Auto_Open i Auto_Close, možda tek malo složenije nego što ste mogli i sami da ih napravite. Sećate se dogovora sa početka: ovaj put otkrivamo jednostavne stvari. Počev od ovih procedura, eksperimentišite dalje, dopunjujte, istražujte. Oprobajte i kombinacije sa Auto_Activate i Auto_Deactivate, koji se vezuju uz određeni list, a potražite i kako se aktiviraju OnEvent procedure.

Procedura Auto_Open

Option Explicit
Dim list As Variant


Sub Auto_Open()
' Radi u Excelu 5/95/...

' isključi osvežavanje ekrana
Application.ScreenUpdating = False

' postavi module na kraj i sakrij ih
Modules.Move after:=Sheets(Sheets.Count)

For Each list In Modules
    list.Visible = False
Next list

' nivo radne sveske
' odričemo se toolbara, linije formula i statusne linije
With Application
   .WindowState = xlMaximized
   .DisplayFullScreen = True
   .DisplayFormulaBar = False
   .DisplayStatusBar = False

   ' ovde se može isključiti automatska rekalkulacija:
   ' .Calculation = xlManual
   ' .MaxChange = 0.001
End With
 
' nivo radnog lista
' ukidamo skrolbarove i tabove
For Each list In Worksheets
    With ActiveWindow
       .DisplayHorizontalScrollBar = False
       .DisplayVerticalScrollBar = False
       .DisplayWorkbookTabs = False
    End With
Next list

' igramo se menijima, tako nam baš treba...
MenuBars(xlWorksheet).Menus("File").Caption = "DATOTEKE"
MenuBars(xlWorksheet).Menus("Help").Caption = "POMOĆ!"
MenuBars(xlWorksheet).Menus("Edit").Enabled = False
MenuBars(xlWorksheet).Menus("Format").Enabled = False

' i jedna nova nova stavka
MenuBars(xlWorksheet).Menus.Add Caption:="NOVI MENI..."

' jedan leteći toolbar...
Toolbars("Microsoft").Visible = True

' dodaj neki svoj makro na vrh Tools menija
MenuBars(xlWorksheet).Menus("Tools").MenuItems.Add _
  Caption:="PE&VAJ!", OnAction:="Pevaj", before:=1

' ovde može da ide i složenije, recimo: 
' OnAction:=ThisWorkBook.Name & "!MakroList2.NekiMakro"

' i jedna linija ispod nove komande
 MenuBars(xlWorksheet).Menus("Tools").MenuItems.Add _
Caption:="-", before:=2

' postavi na prvi list i uključi osvežavanje ekrana
Sheets("PRVI LIST").Select
Application.ScreenUpdating = True

End Sub

Sub Pevaj()
' ovo tek da se nađe... 
MsgBox "Tralala! Tralala! Tralala!"
End Sub

Procedura Auto_Close

Sub Auto_Close()
' Radi u Excelu 5/95/...

' isključi osvežavanje ekrana
Application.ScreenUpdating = False

' postavi module na početak i prikaži ih
Modules.Move before:=Sheets(1)
For Each list In Modules
    list.Visible = True
Next list

' vraćamo izgled radne površine na normalu
With Application
   .WindowState = xlMaximized
   .DisplayFullScreen = False
   .DisplayFormulaBar = True
   .DisplayStatusBar = True

   ' vrati automatsku rekalkulaciju:
   ' .Calculation = xlAutomatic
   ' .MaxChange = 0.001
End With

' vraćamo skrolbarove i tabove
For Each list In Worksheets
    With ActiveWindow
       .DisplayHorizontalScrollBar = True
       .DisplayVerticalScrollBar = True
       .DisplayWorkbookTabs = True
    End With
Next list

' isključi toolbar... 
Toolbars("Microsoft").Visible = False

' resetujemo meni na osnovni oblik
MenuBars(xlWorksheet).Reset

' postavi na prvi list i uključi osvežavanje ekrana
Sheets("PRVI LIST").Select
Application.ScreenUpdating = True

End Sub