Microsoft Office Access
uređuje Branislav Mihaljev, MVP

Specifikacija polja tabele

Nivo:
NIVO 2 - Među ovim prilozima se nalaze preporuke koje se uglavnom odnose na bolje snalaženje i efikasniji rad: dodatni trikovi koji će biti svakom od pomoći i koji upućuju na prag napredne upotrebe programa.

Nije svako programiranje namenjeno isključivo aplikaciji, zapravo krajnjem korisniku: uz malo truda, pomoći ćete sami sebi da brže razvijate aplikaciju. Evo jednog sasvim prostog primera - ovaj makro je namenjen autorima Access aplikacija.

Kada radite sa nekom tabelom u Accessu koja ima mnogo polja, dok ste u režimu izmena (Design View) morate često skrolovati po listi da biste videli gde je koje polje. Takođe, može biti zamorno da pamtite tačna imena svih polja dok ih koristite u toku programiranja. Zbog toga, ne bi bilo loše da pripremite kratku referentnu listu polja tabele, pa da držite odštampani papir ili prozor editora pored sebe, kako biste brže radili. U tome će vam pomoći makro ListajPolja koji vidite u prilogu.

Napravite novi modul, pa u njega prenesite ovu proceduru i prateću funkciju. Pre pokretanja, ukoliko već nije otvoreno okno Immediate, otvorite ga (CTRL+G), jer će se izlazni rezultat naći u njemu, odakle možete da ga iskopirate. Dobijenu specifikaciju čini spisak svih polja, a pored svakog će se naći opis tipa polja i njegova dužina.

Sub ListajPolja()

Dim dbBaza As DAO.Database
Dim dbpolje As DAO.Field
Dim tDef As DAO.TableDef

Set dbBaza = CurrentDb
Set tDef = dbBaza.TableDefs!Test

Debug.Print "Naziv tabele: "; tDef.Name
Debug.Print "------------------"

For Each dbpolje In tDef.Fields
   Debug.Print dbpolje.Name & ", " & _
    TipPolja(dbpolje.Type) & " (" & _
    dbpolje.Size & ")"
Next dbpolje

Debug.Print "--------------------------"

End Sub


Function TipPolja(intType As Integer) As String

Select Case intType
   Case 1: TipPolja = "YesNo"
   Case 2: TipPolja = "Byte"
   Case 3: TipPolja = "Integer"
   Case 4: TipPolja = "Long Integer"
   Case 5: TipPolja = "Currency"
   Case 6: TipPolja = "Single"
   Case 7: TipPolja = "Double"
   Case 8: TipPolja = "Date/Time"
   Case 9: TipPolja = "type 9"
   Case 10: TipPolja = "Text"
   Case 11: TipPolja = "OLE Object"
   Case 12: TipPolja = "Memo ili Hyperlink"
   Case 15: TipPolja = "Replication ID"
   Case 20: TipPolja = "Decimal"
   Case Else: TipPolja = "???"
End Select

End Function